#include "colors.inc"
#include "shapes.inc"
#include "stones.inc"

camera {
  location <.5-1*clock,.4,-2.3>
  angle 70
  look_at <0,.1,0>
  rotate z*7*clock
}

atmosphere {
    type 4
    samples 15
    distance 3
    scattering 0.4
    aa_level 4
    aa_threshold 0.16
    jitter 0.4
}

light_source {  // dim light from front, below
  <2,.3,-3>,White*.8
  atmosphere off
}
light_source { // bright bright spotlight behind, pointing -Z
  <0,0,1.8>,<3.5,4,5>*4
  spotlight
  radius 20
  point_at <0,0,-2>
  falloff 25
  atmospheric_attenuation on  
}


#declare obj=
sphere { 0,1
 
}

#declare crack=
height_field { 
  gif "plasma2.gif"
  smooth 
  scale <2,.3,2>
  translate <-1,0,-1>
  
  scale 1
}

#declare split=.4*clock

union {
  intersection {
    object { obj }
    union { object { crack } inverse }
    translate <0,split/2,0>
  }
  intersection {
    object {obj}
    object {crack} 
    translate <0,-split/2,0>
  }
  texture{
     T_Grnt20
     scale <2, 5, 2> 
     rotate <0, 0, 50>
     finish{ambient 0.2 crand 0.06}
     scale .1
  }  
}